//equation de la chaleur 1D CL Dirirchlet
//parametres physique et numérique
L=2;
Nx=160;
h=L/(Nx+1);
x=[h:h:L-h]';
dt=0.01;
Tfin=2;
// matrice du laplacien 1D Diriclet: Mdir
Mdir=2*diag(sparse(ones(Nx,1)),0)-diag(sparse(ones(Nx-1,1)),1)-diag(sparse(ones(Nx-1,1)),-1);

Mdir=Mdir/h^2;

// matrice Id/dt: Idsdt
Idsdt=1/dt*diag(sparse(ones(Nx,1)),0);
//matrice du pb elliptique
mat=Idsdt+Mdir;
//
//construction de la donnee initiale
U=zeros(Nx,1);
U(Nx/4:3*Nx/4)=1;
//U=sin(x).^2;
plot2d(x,U,style=5)
//
tempsimp=0;
//construction de U^n+1 en fonction de U^n
for temps=dt:dt:Tfin
    SM=U/dt;
    U=mat\SM;
    tempsimp=tempsimp+dt;
    if tempsimp>0.0125
        tempsimp=0
        plot2d(x,U)
    end 
end

